[vladikcomper]

Thorn, on 11 March 2013 - 01:57 PM, said:

vladikcomper: let me ask the obvious question, then... wouldn't it be practical to set up your driver starting from the Sonic 2 "clone" sound driver (a public, on-the-wiki port of the Sonic 1 sound driver to Sonic 2)? Granted, it's not 100% identical, but it does move things back to SMPS 68k. You've probably already thought of that and it's just not obvious in your answer, but I figured I should ask directly. I've considered looking into it myself, but :effort:.

Ehh, frankly, I totally forgot about Clone Driver =P

I've heard of it, but never used it myself, because I'm not hacking Sonic 2 per se. But considering it's 68K nature, this is definitely what I should be looking for. Thanks mentioning it. But that said, I'm still interested in pulling this thing with the original Sonic 2's sound driver.

EDIT: Quoted due to new page

This post has been edited by vladikcomper: 14 March 2013 - 02:53 PM

[ashthedragon]

Stupid question but...Can I have an already compiled .bin of Sonic 1 with the mega PCM driver working? I want to try it at real hardware but I've no idea of hot to compile asm

[vladikcomper]

ashthedragon, on 23 March 2013 - 06:37 PM, said:

Stupid question but...Can I have an already compiled .bin of Sonic 1 with the mega PCM driver working? I want to try it at real hardware but I've no idea of hot to compile asm

Here you go: https://dl.dropbox.c...h_MegaPCM_HQ.7z
This example features Mega PCM playing a digital song on the title screen and replaces some DAC samples in game.

Actually, I've already showed two Sonic 1 disassemblies with Mega PCM in this topic. Both of them also have already compiled ROM for your convenience, see s1built.bin file.

Also, compiling a disassembly is pretty easy, just run build.bat file. If everything is successful, assembler will generate a ROM file for you. It's usually named s1built.bin in case of a Sonic 1 disassembly.

[ashthedragon]

Thank you!

[You-Are-Pwned]

I just checked that version. Is it intentional that the Final Zone music plays in SBZ3? Could be a bug.

[vladikcomper]

You-Are-Pwned, on 29 March 2013 - 07:49 AM, said:

I just checked that version. Is it intentional that the Final Zone music plays in SBZ3? Could be a bug.

This is intentional. As well as different music in GHZ 2 and 3 and somewhere else.

Because this isn't exactly a clean Hivebrain's disassembly, secretly, this is S1 Hacking Studio 2.0 version of disassembly, so I quickly did some music swaps and game tweaks because I was bored. A bit modified disassembly doesn't affect the way you apply Mega PCM guides at all.

[PsychoSk8r]

Anyone else working with the attempt to get this running in Sonic 2?
So far, I've managed to use the Sonic 2 Clone Driver as a base to follow this guide, doing what's required along the way for compatibility, to get this in the game, The game runs, SMPS files that came with the clone driver play (running on the "MegaPCM.z80" Driver), but I'm getting garbled DAC ingame.
Excuse the poor host, but here's my resulting ROM:
http://www.mediafire...f8s9ydxvyo9pjnv
Kick and Snare are in there, but as ASM code instead ("dc.b"), as I'm having trouble with bincludes. Timpani is replaced with the kick sample for now. Oddly enough, the kick plays perfectly instead of the Sega Sound on the Sega Screen.

Edit: After some more inspection, and getting the BINCLUDES working correctly (thanks to mainmemory), It appears that it was struggling to play the samples provided with MegaPCM, I used some custom uncompressed samples from a while ago, and it worked. I'm checking now whether it will take some compressed samples I've had laying around.

This post has been edited by PsychoSk8r: 09 April 2013 - 05:26 PM

[vladikcomper]

Good job, PsychoSk8r!

I'm planning do a Clone Driver port as well and write a full guide, but I don't know when I can start, because now I have few other things I should finish first. Hope to get on it this month, eventually.

As for the garbled DACs issue you had, hearing how it sounds in the ROM you've provided, it looks like Mega PCM is trying to play compressed DPCM samples as uncompressed PCM. Ensure you've changed 'pcm' to 'dpcm' in playback flags for the compressed samples.

[PsychoSk8r]

I'm glad you'll take a look too, you're bound to know MPCM better than anyone else. =P
I've never been too big on hacking S2, but I have ported objects/routines between S1/S2 in the past (to test my limits). The Sound Driver is in, supports uncompressed custom samples, but I'll be damned if I can get dpcm working lol.
http://www.mediafire...9po8fbbx88c1cz8

Here are my results, complete disassembly, some bonus DAC samples I've had laying around. It's not quite there yet, but getting there. Hopefully this might help you a little.
Apologies if there are any files in there that shouldn't be, I did give the folders a quick once-over to remove unnecessary files. I think I may have left a rather large "DAC Sample" in the DAC folder (copied straight from a side-project). =P

[ValleyBell]

The fixed IncludeDAC macro for the Xenowhirl disassembly is:

IncludeDAC macro Name,Extension
Name:		label	*
	binclude	"dac/Name.Extension"
Name_End:	label	*
	endm

It took me a while to figure this out when I adding nicer sample tables to S2 Recreation.

[PsychoSk8r]

Haha, sweet. That should keep things neater. There's got to be some data somewhere on how macros work differently with the two assemblers. Such a shame we don't have one assembler that's supported globally. Also, the "strcmp" (which I loved the usage of in this case) added to the IncludeDAC macro is incompatible. Googling for a compatible alternative yielded no results. =P

[ValleyBell]

The AS manual has an example in Chaper 3.4.1 where two strings are compared in a sort of case insensitive way.
But there's indeed a lack of documentation for the assemblers. At least a txt with a link to the assembler manuals somewhere in the disassembly would be nice.

[PsychoSk8r]

Excellent link. I think perhaps we should attempt to provide documentation with each disassembly, perhaps just throw in a new folder "_Docs" or something. It could be immense amounts of help to anyone trying to familiarise themselves, or porting code. The biggest challenge faced with porting large amounts of code is compatibility between assemblers, I've found.
Thanks for that link. =P

[Caverns 4]

I would like to see this able to work in Sonic 2. Partly because that's what I am hacking, but also partly because the page for porting the Sonic 1 sound driver into Sonic 2 provides an ASM file that looks like somebody screwed with it. There's a bunch of unintelligible garbage data in the file, some of with is replacing pointers and addresses. implementing this might be a good solution even if it's a little more (lot more) advanced than what I was to do.

It looks really awesome, excellent work! I didn't know the genesis was capable of this!

[Clownacy]

Building on what I gathered from the previous posts, I have compiled a guide on porting the Mega PCM driver to the Sonic 2 Clone Driver. Included in the guide is a fix for the DPCM bug, and Sonic 2 compatible Z80 stop and VBlank/V_Int optimisations.

Update 17/12/13 dd/mm/yy General clean up. Fixed some factual errors, formatted the last section to a better degree and made the 'Optimizing Z80 stops in SMPS' section an actual guide as opposed to a paragraph long 'I dunno.' Also, new opening.

Spoiler

—INSTALLING MEGA PCM—

Spoiler

Before we can install Mega PCM, we've got to install the Clone Driver, guides can be found here and here. You can install the stock Sonic 1 sound driver if you want to: (here, go nuts), but be aware that this guide does not have that in mind.

Once done, follow the How-To in the main post for installing Mega PCM with the following changes:

• Apply it to Sonic 2 Clone Driver.asm (mainly) and s2.asm (when replacing SoundDriverLoad).
  
• If following mine or Cavern 4's guide on implementing the Clone Driver, replace JmpTo_SoundDriverLoad instead of SoundDriverLoad.
  
• Fix local labels (@Load) (just replace the '@' with '.').
  
• When replacing loc_71EDC, replace all instances of @UnpauseDAC with loc_71EFE.

If you try building your ROM, you'll encounter a lot of errors, not to do with the code modifications you just made, but with MegaPCM.asm itself, with the new assembler and all. Let's get to work on it.

—MAKING MEGAPCM.ASM AS COMPATIBLE—

Spoiler

Open up MegaPCM.asm and replace the IncludeDAC macro with the following (credit to ValleyBell for the original fix, improved by myself):

IncludeDAC macro Name,Extension
Name:		label   *
	if ("Extension"="WAV")
		BINCLUDE	"sound/DAC/Name.Extension",$3A
	else
		BINCLUDE	"sound/DAC/Name.Extension"
	endif
Name_End:	label   *
	endm

This makes the macro compatible with the different assembler.

Replace instances of 'incbin' with 'BINCLUDE', and remove the marks surrounding 'MegaPCM.z80' (or replace them with "), also remove the slashes (/) found in the DAC_Entry and z80word macros. Again, assembler differences.

—PCM TRANSPLANT—

Spoiler

Now build your ROM, open the result in your emulator of choice and proceed to have your ears blasted. This is that DPCM failure. So, if you look around the previous posts, you'll get the idea to just "decompress" the DPCMs. While that is a suitable workaround, that's just it, it's a workaround, not a fix, and believe me it will bite you in the arse later on, as mentioned above. However, for the sake of you, the hacker, experiencing your progress first-hand instead of me just telling you how it's going, we'll go ahead and "decompress" the samples, use JMan's s1sndcomp tool (link here) or any other DPCM to PCM converter and "decompress" each sample (three in all) to "Kick.raw", "Snare.raw", and "Timpani.raw".

Now modify the pointers in MegaPCM.asm to point to the .raw files: Replace the 'dpcm' flags with 'pcm' and in the Samples Files, replace the instances of 'bin' with 'raw'. Build and test.

The results should be pleasing... for now: You'll notice certain samples not play in several instances such as Emerald Hill's intro and Metropolis, whose sole duty is now to deafen you. But this is all to be expected, right? Well, there are only three samples registered to Mega PCM while, as you may guess, stock Sonic 2 includes more, seven in total to be exact, so let's get to adding those.

Open your sound folder and locate the following files:

• dac1d.bin
  
• dac2d.bin
  
• dac3d.bin
  
• dac4d.bin
  
• dac5d.bin
  
• dac6d.bin
  
• dac7d.bin

Throw these into your DAC folder (not the one inside your sound folder) and, for the sake of user-friendliness, rename them:

• DAC1KICK.BIN
  
• DAC2SNARE.BIN
  
• DAC3CLAP.BIN
  
• DAC4SCRATCH.BIN
  
• DAC5TIMPANI.BIN
  
• DAC6TOM.BIN
  
• DAC7BONGO.BIN

Now "decompress" them, following the same name scheme, but with the .raw file extension.

Once again, we've got to modify the pointers to use the new samples, but first we need a guideline:

Take a peek inside Sonic 2 Clone Driver.asm and find the label PCM_Table, it should look like this:

PCM_Table:	dc.l	$A00200, DAC1
		dc.w	$352
		dc.b	$19,0
		dc.l	$A00208, DAC2
		dc.w	$770
		dc.b	$4,0
		dc.l	$A00210, DAC3
		dc.w	$576
		dc.b	$8,0
		dc.l	$A00218, DAC4
		dc.w	$BB5
		dc.b	$A,0
		dc.l	$A00220, DAC5
		dc.w	$1016
		dc.b	$1D,0
		dc.l	$A00228, DAC6
		dc.w	$622
		dc.b	$C,0
		dc.l	$A00230, DAC7
		dc.w	$5C4
		dc.b	$1D,0

Would you look at that, the similarities make porting this all the easier. See the first value in each dc.b entry? That's our tempo/pitch, and the DACX (X being a number) in the dc.l? Well, you can guess what that is. Apply these values to the Samples Table in MegaPCM.asm, you should be left with this:

; ---------------------------------------------------------------
; DAC Samples Table
; ---------------------------------------------------------------

	DAC_Entry		$19, DAC1KICK, pcm			; $81	- Kick
	DAC_Entry		$04, DAC2SNARE, pcm			; $82	- Snare
	DAC_Entry		$08, DAC3CLAP, pcm			; $83	- Clap
	DAC_Entry		$0A, DAC4SCRATCH, pcm			; $84	- Scratch
	DAC_Entry		$1D, DAC5TIMPANI, pcm			; $85	- Timpani
	DAC_Entry		$0C, DAC6TOM, pcm			; $86	- Tom
	DAC_Entry		$1D, DAC7BONGO, pcm			; $87	- Bongo

MegaPCM_End:

Also, below it, modify the Samples Files table to include the new samples, doing so should give you this:

; ---------------------------------------------------------------
; DAC Samples Files
; ---------------------------------------------------------------

	IncludeDAC	DAC1KICK, raw
	IncludeDAC	DAC2SNARE, raw
	IncludeDAC	DAC3CLAP, raw
	IncludeDAC	DAC4SCRATCH, raw
	IncludeDAC	DAC5TIMPANI, raw
	IncludeDAC	DAC6TOM, raw
	IncludeDAC	DAC7BONGO, raw
	even

Now, save and build.

But wait, we're missing something! Play the end of act theme and listen to the music's DAC channel, it goes blank partway through! You can find the cause by examining the original MegaPCM.asm.

; ---------------------------------------------------------------
; DAC Samples Table
; ---------------------------------------------------------------

	DAC_Entry	$08, Kick, dpcm			; $81	- Kick
	DAC_Entry	$08, Snare, dpcm		; $82	- Snare
	DAC_Entry	$1B, Timpani, dpcm		; $83	- Timpani
	dc.l	0,0					; $84	- <Free>
	dc.l	0,0					; $85	- <Free>
	dc.l	0,0					; $86	- <Free>
	dc.l	0,0					; $87	- <Free>
	DAC_Entry	$12, Timpani, dpcm		; $88	- Hi-Timpani
	DAC_Entry	$15, Timpani, dpcm		; $89	- Mid-Timpani
	DAC_Entry	$1B, Timpani, dpcm		; $8A	- Mid-Low-Timpani
	DAC_Entry	$1D, Timpani, dpcm		; $8B	- Low-Timpani

Notice the entries at the bottom? They're additional Timpani entries! Each defines a unique pitch/tempo (with the exception of Mid-Low-Timpani), and if you listen to stock Sonic 2, you'll find that it is these Timpani samples that are missing from the current port! The fix is simple; copy and paste them over and adjust the pitch, as such:

; ---------------------------------------------------------------
; DAC Samples Table
; ---------------------------------------------------------------
PCM_Table:
        DAC_Entry       $19, DAC1KICK, pcm                      ; $81   - Kick
        DAC_Entry       $04, DAC2SNARE, pcm                     ; $82   - Snare
        DAC_Entry       $08, DAC3CLAP, pcm                      ; $83   - Clap
        DAC_Entry       $0A, DAC4SCRATCH, pcm                   ; $84   - Scratch
        DAC_Entry       $1D, DAC5TIMPANI, pcm                   ; $85   - Timpani
        DAC_Entry       $0C, DAC6TOM, pcm                       ; $86   - Tom
        DAC_Entry       $1D, DAC7BONGO, pcm                     ; $87   - Bongo
	DAC_Entry       $14, DAC5TIMPANI, pcm                   ; $88   - Hi-Timpani
	DAC_Entry       $17, DAC5TIMPANI, pcm                   ; $89   - Mid-Timpani
	DAC_Entry       $1E, DAC5TIMPANI, pcm                   ; $8A   - Low-Timpani
	DAC_Entry       $1F, DAC5TIMPANI, pcm                   ; $8B   - Floor-Timpani

You see here, the pitch/tempo of these instruments differs between Sonic 1 and 2, these new values can be found under byte_71CC4 in Sonic 2 Clone Driver.asm. With that out of the way, save and build.

Alright, we're in business now; all instruments ported, everything sounds okay as far as the title screen and Emerald Hill go, I guess we're done here! Nope, we've still got the problem of getting the DPCMs working again, and give Metropolis Zone a listen. Yep, it's still there. Even though DAC4SCRATCH is included and is in the right place.

—FIXING DPCM—

Spoiler

So, remember PCM_Table? It's still there, double defining and double including sound samples, let's get rid of it.

Mosey on over to PCM_Table and delete or comment it out, the entire table:

Now move to the end of Sonic 2 Clone Driver.asm and find this:

		align $8000
DAC1: BINCLUDE sound\dac1d.bin
		even
DAC2: BINCLUDE sound\dac2d.bin
		even
DAC3: BINCLUDE sound\dac3d.bin
		even
DAC4: BINCLUDE sound\dac4d.bin
		even
DAC5: BINCLUDE sound\dac5d.bin
		even
DAC6: BINCLUDE sound\dac6d.bin
		even
DAC7: BINCLUDE sound\dac7d.bin
		even

Delete it.

So what about Calculate_PCM? It's still pointing to PCM_Table! Delete that too, along with the Calc_PCM2 found below it. But now we've got to remove the references to Calculate_PCM to avoid 'symbol undefined' errors. Search and delete all instances of "jsr Calculate_PCM". From what I can tell, this is a part of JMan's DAC driver, which was integrated into the Clone Driver a while back. It and Mega PCM don't get along.

That should do it. Save, build, and test. Mega PCM should now be fully working, even Metropolis is cooperating! Now for the part we've all been waiting for: Efficiency(!) Change MegaPCM.asm to use the "compressed" samples (DAC1KICK.BIN, etc) by changing the "raw"s in the Sample Files table to "bin"s, and the "pcm"s in the Samples Table to "dpcm"s.

Upon saving and building, the DPCMs should now play ungarbled, mission accomplished!

As a note, playing samples such as the Sonic CD 1up "yes" come out scratchy, so Vladikcomper's optimisations will have to be ported. Guess what we're doing next?

—REMOVING THE PITCH-SHIFTERS—

Spoiler

Nope. Remember when the additional timpani pitches stopped working? We somehow left these two functions intact but broken: the remnants still handle alternate tom and bongo pitches. As with the timpani, we must add these to the Samples Table and eliminate the remnants. We'll start with familiar ground and begin with the former.

Look for byte_71CC4 again, and you'll find this:

byte_71CC4:	dc.b $14, $17, $1E, $1F
Tom_71CC4: dc.b $4, $7, $A, $FF
Bongo_71CC4: dc.b $A, $D, $14, $FF

The first list contains the timpani tempos we used earlier, the second contains the tom tempos, and the third holds the bongo tempos. Adding this to the Samples Table should give you this:

        DAC_Entry       $19, DAC1KICK,		dpcm	; $81	- Kick
        DAC_Entry       $04, DAC2SNARE,		dpcm	; $82	- Snare
        DAC_Entry       $08, DAC3CLAP,		dpcm	; $83	- Clap
        DAC_Entry       $0A, DAC4SCRATCH,	dpcm	; $84	- Scratch
        DAC_Entry       $1D, DAC5TIMPANI,	dpcm	; $85	- Timpani
        DAC_Entry       $0C, DAC6TOM,		dpcm	; $86	- Tom
        DAC_Entry       $1D, DAC7BONGO,		dpcm	; $87	- Bongo
	DAC_Entry       $14, DAC5TIMPANI,	dpcm	; $88	- Hi-Timpani
	DAC_Entry       $17, DAC5TIMPANI,	dpcm	; $89	- Mid-Timpani
	DAC_Entry       $1E, DAC5TIMPANI,	dpcm	; $8A	- Low-Timpani
	DAC_Entry       $1F, DAC5TIMPANI,	dpcm	; $8B	- Floor-Timpani
	DAC_Entry	$04, DAC6TOM,		dpcm	; $8C	- Hi-Tom
	DAC_Entry	$07, DAC6TOM,		dpcm	; $8D	- Mid-Tom
	DAC_Entry	$0A, DAC6TOM,		dpcm	; $8E	- Low-Tom
	DAC_Entry	$FF, DAC6TOM,		dpcm	; $8F	- Floor-Tom
	DAC_Entry	$0A, DAC7BONGO,		dpcm	; $90	- Hi-Bongo
	DAC_Entry	$0D, DAC7BONGO,		dpcm	; $91	- Mid-Bongo
	DAC_Entry	$14, DAC7BONGO,		dpcm	; $92	- Low-Bongo
	DAC_Entry	$FF, DAC7BONGO,		dpcm	; $93	- Floor-Bongo

Hang on, why are the floor entries $FF? The most likely answer is that the floor entries borrow the tempos of the default tom and bongo entries.

        DAC_Entry       $0C, DAC6TOM,		dpcm	; $86	- Tom
        DAC_Entry       $1D, DAC7BONGO,		dpcm	; $87	- Bongo

These ones.

In any case, they sound better than $FF so let's replace them with those.

        DAC_Entry       $19, DAC1KICK,		dpcm	; $81	- Kick
        DAC_Entry       $04, DAC2SNARE,		dpcm	; $82	- Snare
        DAC_Entry       $08, DAC3CLAP,		dpcm	; $83	- Clap
        DAC_Entry       $0A, DAC4SCRATCH,	dpcm	; $84	- Scratch
        DAC_Entry       $1D, DAC5TIMPANI,	dpcm	; $85	- Timpani
        DAC_Entry       $0C, DAC6TOM,		dpcm	; $86	- Tom
        DAC_Entry       $1D, DAC7BONGO,		dpcm	; $87	- Bongo
	DAC_Entry       $14, DAC5TIMPANI,	dpcm	; $88	- Hi-Timpani
	DAC_Entry       $17, DAC5TIMPANI,	dpcm	; $89	- Mid-Timpani
	DAC_Entry       $1E, DAC5TIMPANI,	dpcm	; $8A	- Low-Timpani
	DAC_Entry       $1F, DAC5TIMPANI,	dpcm	; $8B	- Floor-Timpani
	DAC_Entry	$04, DAC6TOM,		dpcm	; $8C	- Hi-Tom
	DAC_Entry	$07, DAC6TOM,		dpcm	; $8D	- Mid-Tom
	DAC_Entry	$0A, DAC6TOM,		dpcm	; $8E	- Low-Tom
	DAC_Entry	$0C, DAC6TOM,		dpcm	; $8F	- Floor-Tom
	DAC_Entry	$0A, DAC7BONGO,		dpcm	; $90	- Hi-Bongo
	DAC_Entry	$0D, DAC7BONGO,		dpcm	; $91	- Mid-Bongo
	DAC_Entry	$14, DAC7BONGO,		dpcm	; $92	- Low-Bongo
	DAC_Entry	$1D, DAC7BONGO,		dpcm	; $93	- Floor-Bongo

With that done, we can remove the pitch-shifting code.

loc_71C88:
		move.l	a4,4(a5)
		btst	#2,(a5)
		bne.s	locret_71CAA
		moveq	#0,d0
		move.b	$10(a5),d0
		cmpi.b	#$80,d0
		beq.s	locret_71CAA
		cmp.b   #0,($FFFFFF3A).w
		bgt.s	locret_71CAA
		cmp.b	#$8C,d0
		bge.s	loc_71CAC
		move.b	d0,($A01FFF).l


locret_71CAA:
		rts

Our problem stems from loc_71C88, seen here. It checks for a DAC value above $8C, and if so, branches to a subroutine which handles each instrument and pitch. This isn't the first we've seen of this system: A smaller version can be found in Sonic 1, though it only handles the timpani. Anyway, this is now redundant, and soon, it will become a hindrance, so we'd best remove it. We shall begin by removing the branch, also, it might be worth removing the one above it too, it check an unused RAM address that's never written to, it's useless. You should be left with this:

loc_71C88:
		move.l	a4,4(a5)
		btst	#2,(a5)
		bne.s	locret_71CAA
		moveq	#0,d0
		move.b	$10(a5),d0
		cmpi.b	#$80,d0
		beq.s	locret_71CAA
		move.b	d0,($A01FFF).l


locret_71CAA:
		rts

Now to finally be rid of this code. Starting with loc_71CAC, we shall remove the code before reaching its end at sub_71CCA.

Find and delete this code:

loc_71CAC:
		cmpi.b	#$8C,d0
		beq.w	Tom_71CAC
		cmpi.b	#$8D,d0
		beq.w	Tom_71CAC
		cmpi.b	#$8E,d0
		beq.w	Tom_71CAC
		cmpi.b	#$8F,d0
		beq.w	Bongo_71CAC
		cmpi.b	#$90,d0
		beq.w	Bongo_71CAC
		cmpi.b	#$91,d0
		beq.w	Bongo_71CAC
		move.l	d0,-(sp)
		move.b  #$85,d0
		move.l  (sp)+,d0
		subi.b	#$88,d0
		move.b	byte_71CC4(pc,d0.w),d0
		move.b	d0,($A00224).l
		move.b	#$85,($A01FFF).l
		rts

Tom_71CAC:
		move.l	d0,-(sp)
		move.b  #$86,d0
		move.l  (sp)+,d0
		subi.b	#$8C,d0
		move.b	Tom_71CC4(pc,d0.w),d0
		move.b	d0,($A0022C).l
		move.b	#$86,($A01FFF).l
		rts

Bongo_71CAC:
		move.l	d0,-(sp)
		move.b  #$87,d0
		move.l  (sp)+,d0
		subi.b	#$8F,d0
		move.b	Bongo_71CC4(pc,d0.w),d0
		move.b	d0,($A00234).l
		move.b	#$87,($A01FFF).l
		rts

NoBend_71CAC:
		move.b	d0,d1
		subi.b	#7,d1
		move.b  d1,d0
		move.b	d0,($A01FFF).l
		bra.w	locret_71CAA

; End of function sub_71C4E

; ===========================================================================
byte_71CC4:	dc.b $14, $17, $1E, $1F
Tom_71CC4: dc.b $4, $7, $A, $FF
Bongo_71CC4: dc.b $A, $D, $14, $FF

With that finally eliminated, we can move on to Vladikcomper's optimisations!

—OPTIMISING Z80 STOPS—

Spoiler

Follow Vladikcomper's guide with the following changes:

• Apply guide to Sonic 2 Clone Driver.asm.
  
• You only have to define the waitYM macro.
  
• To fix an error with the original guide, comment out or remove the three lines below the ones detailed in the first part of the guide. Not doing so will cause your ROM to hang upon booting, infinitly checking for something that will never happen.
  
  

  sub_71B4C:
  ;		move.w	#$100,($A11100).l ; stop the Z80
  ;		nop	
  ;		nop	
  ;		nop	
  
  loc_71B5A:								; <--	Delete
  		btst	#0,($A11100).l		; Is the z80 busy?	; <--	Delete
  		bne.s	loc_71B5A		; If so, wait		; <--	Delete
  

—OPTIMISING VBLANK ROUTINES—

Spoiler

PCM playback quality is dragged down by unnecessary Z80 interruptions. Here, we'll see to removing these. Most of them are in V-Int, though there are notable instances elsewhere.

First, search for this:

dma68kToVDP Sprite_Table_2,VRAM_Sprite_Attribute_Table,VRAM_Sprite_Attribute_Table_Size,VRAM

You should find it sandwiched between a stop and a start. Delete these first two. That covers H-Int

Now, onto V-Int.

• VintSub0 (if you haven't already deleted them while removing sndDriverInput)
  
• loc_4C4, the other at loc_54A
  
• Vint0_noWater
  
• VintSub14
  
• VintSub8, the other is at loc_748
  
• Vint10_specialStage, the other at loc_86E
  
• VintSubA, with the other way over above loc_9B8
  
• VintSub1A
  
• VintSubC, with the other being at loc_BD6
  
• VintSub18
  
• VintSub16
  
• Do_ControllerPal, the other at loc_EFE

Now for the rest.

• JoypadInit
  
• ClearScreen
  
• EndingSequence

—REFORMATTING—

Spoiler

Slapping this all together, saving, and building will produce some... odd results. Turns out we were wrong. Our table is inaccurate. Very inaccurate. Really, the toms, timpani, and bongos are all over the place. Listen to the options theme, the act complete theme, MCZ 2 player theme, it's ridiculous. Our current table is this:

        DAC_Entry       $19, DAC1KICK,		dpcm	; $81	- Kick
        DAC_Entry       $04, DAC2SNARE,		dpcm	; $82	- Snare
        DAC_Entry       $08, DAC3CLAP,		dpcm	; $83	- Clap
        DAC_Entry       $0A, DAC4SCRATCH,	dpcm	; $84	- Scratch
        DAC_Entry       $1D, DAC5TIMPANI,	dpcm	; $85	- Timpani
        DAC_Entry       $0C, DAC6TOM,		dpcm	; $86	- Tom
        DAC_Entry       $1D, DAC7BONGO,		dpcm	; $87	- Bongo
	DAC_Entry       $14, DAC5TIMPANI,	dpcm	; $88	- Hi-Timpani
	DAC_Entry       $17, DAC5TIMPANI,	dpcm	; $89	- Mid-Timpani
	DAC_Entry       $1E, DAC5TIMPANI,	dpcm	; $8A	- Low-Timpani
	DAC_Entry       $1F, DAC5TIMPANI,	dpcm	; $8B	- Floor-Timpani
	DAC_Entry	$04, DAC6TOM,		dpcm	; $8C	- Hi-Tom
	DAC_Entry	$07, DAC6TOM,		dpcm	; $8D	- Mid-Tom
	DAC_Entry	$0A, DAC6TOM,		dpcm	; $8E	- Low-Tom
	DAC_Entry	$0C, DAC6TOM,		dpcm	; $8F	- Floor-Tom
	DAC_Entry	$0A, DAC7BONGO,		dpcm	; $90	- Hi-Bongo
	DAC_Entry	$0D, DAC7BONGO,		dpcm	; $91	- Mid-Bongo
	DAC_Entry	$14, DAC7BONGO,		dpcm	; $92	- Low-Bongo
	DAC_Entry	$1D, DAC7BONGO,		dpcm	; $93	- Floor-Bongo


MegaPCM_End:

SMPS2ASM gives us the answer (you could probably find the answer in s2.sounddriver.asm as well), look at the DAC equates.

	elseif SonicDriverVer==2
		enum dKick=$81,dSnare,dClap,dScratch,dTimpani,dHiTom,dVLowClap,dHiTimpani,dMidTimpani
		enum dLowTimpani=dMidTimpani+1,dVLowTimpani,dMidTom,dLowTom,dFloorTom,dHiClap
		enum dMidClap=dHiClap+1,dLowClap

Note that all clap entries but the first are actually bongo entries. Applying this to our Samples Table gives us:

        DAC_Entry       $19, DAC1KICK,		dpcm	; $81	- Kick
        DAC_Entry       $04, DAC2SNARE,		dpcm	; $82	- Snare
        DAC_Entry       $08, DAC3CLAP,		dpcm	; $83	- Clap
        DAC_Entry       $0A, DAC4SCRATCH,	dpcm	; $84	- Scratch
        DAC_Entry       $1D, DAC5TIMPANI,	dpcm	; $85	- Timpani
	DAC_Entry	$04, DAC6TOM,		dpcm	; $86	- Hi-Tom
	DAC_Entry	$FF, DAC7BONGO,		dpcm	; $87	- Low-Bongo
	DAC_Entry       $14, DAC5TIMPANI,	dpcm	; $88	- Hi-Timpani
	DAC_Entry       $17, DAC5TIMPANI,	dpcm	; $89	- Mid-Timpani
	DAC_Entry       $1E, DAC5TIMPANI,	dpcm	; $8A	- Mid-Low-Timpani
	DAC_Entry       $1F, DAC5TIMPANI,	dpcm	; $8B	- Low-Timpani
	DAC_Entry	$07, DAC6TOM,		dpcm	; $8C	- Mid-Tom
	DAC_Entry	$0A, DAC6TOM,		dpcm	; $8D	- Mid-Low-Tom
	DAC_Entry	$FF, DAC6TOM,		dpcm	; $8E	- Low-Tom
	DAC_Entry	$0A, DAC7BONGO,		dpcm	; $8F	- Hi-Bongo
	DAC_Entry	$0D, DAC7BONGO,		dpcm	; $90	- Mid-Bongo
	DAC_Entry	$14, DAC7BONGO,		dpcm	; $91	- Mid-Low-Bongo
;       DAC_Entry       $0C, DAC6TOM,		dpcm	; $XX	- Tom	; Unneeded
;       DAC_Entry       $1D, DAC7BONGO,		dpcm	; $XX	- Bongo	; Unneeded


MegaPCM_End:

With this we no longer need those two tom and bongo entries from the top, turns out they were unused and unneeded the entire time, well, unless you count the floor entries mimicking them. With that done, we are now finished. You can add samples and play them back with no scratchiness.

...

Oh wait.

—PLAYING SAMPLES—

Spoiler

Riiiiight, the samples. One last bit, when using samples in this manner:

	moveq   #$FFFFFF84,d0
	jsr     PlaySample

Make the moveq value byte length, so you have:

	moveq   #$84,d0
	jsr     PlaySample

Leaving it the way it is will just give you an error.

Information stream:

Spoiler

Timpani Troubles

Spoiler

EDIT:Noticed some missing (Timpani?) notes in the act complete music, Sonic 1 Mega PCM had separate instances of Timpani defined with unique pitches, and upon trying to add a sample of my own in both slot 88 and slot 8C (with dc.l 0,0 filling the 88, 89, 8A, and 8B slots), the first missing note would play the sample, Stock Sonic 2 Clone Driver doesn't appear to manage it this way, looking into alternate pitches. This makes the 1up jingle DAC-less, as its entire DAC library consists of these missing notes.

EDIT2: I copied the values found in the Sonic 1-ready MegaPCM.asm to the Sonic 2-compatable MegaPCM.asm and increased each entry's pitch by two to match the main Timpani sample's. This fixed all missing samples, however, I am unsure as to whether the pitch is correct, I don't have much of an ear for these things. Pushing new information to guide.

EDIT6: There are now some missing notes in the options and level select theme, this is brought on by the Z80 stop optimisations. Great! Optimisations have been relocated until fix is found.

EDIT8: Everything related to Calculate_PCM has been removed. This has fixed the above problem. Calculate PCM was a workaround for the missing instrument, the timpani pitches, the tom, and the bongo, an alternative to simply adding them to the DAC entry list as we did with the timpani. Turns out we didn't remove it fully. It was enough to get the scratch working, but the optimisations dealt the killing blow to the undead Calculate_PCM, and the tom and bongo samples simply came out mute. Adding information on fully removing Calculate_PCM, along with re-adding the optimisations guide complete with a new section, now.

EDIT7: While adding HG comments to Sonic 2 Clone Driver.asm, I discovered the true timpani pitches; $14, $17, $1E, and $1F. Also found are the true names of instruments BOP and COWBELL, which have been identified as Tom and Bongo. Findings pushed to guide.

MD.crash

Spoiler

EDIT3: It would appear that I broke something, as DAC now crashes MD.emu, while Sonic 1 (outfitted with Mega PCM) works fine. Fusion works though. The most interesting part is that MD.emu works with ROMs where the DPCM hasn't been fixed, looking into Sonic 1 Calculate_PCM equivalent for fix (EDIT: This was before I was aware that the Clone Driver used Jman's DAC driver, which is the origin of Calculate_PCM.)

EDIT4: No equivalent found. Investigating how to eliminate Calculate_PCM.

EDIT5: Fix was pretty simple; remove all references to Calculate_PCM, which was as easy as just commenting out the "jsr Calculate_PCM"s doted around Sonic 2 Clone Driver.asm, pushing new info to guide. This eliminates a good chunk of the "Fixing DPCM" section.

Optimizing Z80 stops in SMPS

Spoiler

EDIT6: I've ported the optimisations to allow high quality sample playback. Information pushed to guide.

EDIT6: There are now some missing notes in the options and level select theme, this is brought on by the Z80 stop optimisations. Great! Optimisations have been relocated until fix is found.

EDIT8: Everything related to Calculate_PCM has been removed. This has fixed the above problem. Calculate PCM was a workaround for the missing instrument, the timpani pitches, the tom, and the bongo, an alternative to simply adding them to the DAC entry list as we did with the timpani. Turns out we didn't remove it fully. It was enough to get the scratch working, but the optimisations dealt the killing blow to the undead Calculate_PCM, and the tom and bongo samples simply came out mute. Adding information on fully removing Calculate_PCM, along with re-adding the optimisations guide complete with a new section, now

Original post:

Spoiler

I've got it! Sonic 2 Clone Driver DPCM functionality regained!

Okay, so I've been fooling around with this for a while but gave up when logic died on me: I had ported Mega PCM to the Clone Driver and applied its PCM_Table to MegaPCM.asm, allowing me full DAC accuracy and instruments, but, as has been said before, the samples could only play in raw PCM, I just worked around this by "decompressing" (I use the marks because they aren't really compressed, not in the traditional sense anyway) all of the samples and moving on... Then I found out that one sample had really messed up: the 'scratch', featured in Metropolis Zone's music, it was the same static-y noise heard upon trying to play a DPCM sample in the port's current, buggy state, except this sample was standard uncompressed 8-bit stereo PCM just like all the others, so what happened? This confused me to the point of abandoning the project and deeming Mega PCM unportable by my own means, as I had tried every conceivable method of fixing it, all to no avail. However, a month later, curiosity got the better of me and I had one final shot at it. What are the chances that I fix it first try, and in a matter of seconds, no less? Well, there's newbie luck for you.

Here's a long and dragged out how-to!

This post has been edited by Clownacy: 01 March 2015 - 09:53 AM